Na endlich... nach vielen Stunden ist es doch noch gelungen
Wenn im Netz nicht soviel haarsträubender Blödsinn zu finden wäre, hätte ich das schneller geschafft - die schlimmste und sicher auch dämlichste aller Ideen, ist ein "halb-gepatchtes" MSI-Paket mit ORCA zurechtzufrickeln.
Allerdings ist die Dokumentation von Adobe so bescheiden, dass man auf "verständlichere" Erklärungen aus dem Netz angewiesen ist.
Ich war schon fast so weit um auf Foxit-Reader umzusteigen - allerdings landet man da vom Regen in der Traufe.
BOT: Ich habe die Erkenntnisse mal in einer Batch zusammengefasst ....
|
Quellcode
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
@echo off
rem version muss jeweils angepasst werden
set version=1014
set workdir=D:\AcroRead
set aiproot=\\<zentrales Software-Repository (ggf. als DFS)>\acroread_%version%
set unpack=%workdir%\unpack
set exefile=%workdir%\AdbeRdr%version%_de_DE.exe
if NOT exist %exefile% goto FileMiss
if exist %aiproot% goto AipExist
md %aiproot%
if exist %unpack% rd %unpack% /S /Q
echo ######################### Auspacken #########################
%exefile% -nos_o%unpack% -nos_ne
echo ################ Administrative Installation ################
msiexec /a %unpack%\AcroRead.msi /qb TARGETDIR=%aiproot%
echo ########################### Patch ###########################
msiexec /a %aiproot%\AcroRead.msi /p %unpack%\AdbeRdrUpd%version%.msp /qb
rem ACHTUNG: Patch-Logik und Reihenfolge beachten!
echo ################# generische INI erstellen ##################
echo [Startup] >%aiproot%\Setup.ini
echo RequireMSI=3.0 >>%aiproot%\Setup.ini
echo [Product] >>%aiproot%\Setup.ini
echo msi=AcroRead.msi >>%aiproot%\Setup.ini
echo ########### Explorer starten und Dateien pruefen ############
%windir%\explorer.exe /n,/e,/select,%aiproot%
echo Verbleibende Aufgaben:
echo MST mit Customization Wizard erstellen (optional)
echo MSI und ggf. MST per Gruppenrichtlinie installieren.
goto quit
:AipExist
echo Fehler: Verzeichnis %aiproot% bereits vorhanden!
goto quit
:FileMiss
echo Fehler: %exefile% nicht gefunden!
:quit
pause
|
... bei Interesse erkläre ich gerne, was ich hier getrieben habe und was man genau tun muss um das Ding anzupassen.
mfg, Tom